Merellä navigointi perustuu nykyään pääasiallisesti satelliittinavigointiin. Se on toimiessaan tarkka ja käytöltään helppo, mutta se ei kuitenkaan riitä kaiken kattavaksi ulkopuolisista tekijöistä riippumattomaksi varanavigointimenetelmäksi. Tarvitaan varalle ainakin toinen laite, jolla on oma virtalähde.
Varanavigointimenetelmäksi käy myös tähtitieteellinen paikanmääritys. - Mutta miksi tämä aikoinaan hallitseva menetelmä on niin työläs, ettei sitä juuri vapaaehtoisesti harjoiteta, edes varamenetelmänä? Kokemuksiini perustuen tämä johtuu tähtitieteelliseen paikanmääritykseen liittyvistä laskutoimituksista, joiden sovellutusten kehittäminen ei ole pysynyt ajan tasalla.
Vaikka taulukkojen sijaan käytettäisiin näennäisesti yksinkertaisia trigonometrisia yhtälöitä ja laskutoimitukset tehtäisiin funktiolaskimella, eivät rutiinilaskutoimitukset juuri helpotu. Mahdollisuudet virhenäppäilyyn ovat niin suuret, että luotettaviin tuloksiin pääsemiseksi laskut on tehtävä aina useaan kertaan.
Trigonometriaan kuuluvat laskut eivät sitäpaitsi ole ainoat asiaan liittyvät, vaan näiden lisäksi on vielä joukko pienempiä laskuja. Puhumattakaan siitä, että kun kerran vuodessa tai vuosikymmenessä innostutaan harjoittelemaan, on aina ensin kerrattava, mitä sisältyy rutiinilaskuihin.
PALLOTRIGONOMETRIAAN PERUSTUVAT RATKAISUYHTÄLÖT
Taivaankappaleen laskettu korkeus ja suuntima (atsimuutti) voidaan laskea seuraavista yhtälöistä.
Hc = arc sin (sin Lat sin Dec + cos Lat cos Dec cos LHA)
Z = arc cos ((sin Dec - sin Lat sin Hc)/(cos Lat cos Hc))
LASKIMEN OHJELMOINTI
Vaihtoehtona taulukoille ja laskuille löytyy valmiiksi ohjelmoituja laskimia, joiden avuksi ei tarvita muuta kuin kello ja sekstantti. Mutta ohjelmoidutkaan laskimet eivät tuo apua perimmäisiin ongelmiin.
Monet purjehtijat tarvitsevat tähtitieteellistä paikanmääritystä vain harvoin, jolloin valmiiksi ohjelmoidun navigointilaskimen tarve jää lyhytaikaiseksi. Lisäksi laskin ei poista 'Nautikaalin' tarvetta, sillä kaikista elektronisista laitteista huolimatta 'Nautikaali' ja sen käytön hallitseminen tuo turvallisuuden tunnetta navigointiin.
Tähtitieteellisestä paikanmäärityksestä saadaan kuitenkin mielekäs ja helppo harrastus, kun kukin itse ohjelmoi ikävät laskutoimitukset omaan laskimeensa. Tällaista ohjelmointia varten löytyy riittävä lähdeaineisto 'Nautikaalista'. - Alla on esimerkki itse tekemästäni ohjelmasta.
Laskimissa oli aikoinaan standardina Basic-ohjelmointikieli, joskin erilaisia murteita saattoi niissä olla. Yhteistä laskimille oli kuitenkin rajoitettu kapasiteetti sekä muistissa että näyttöruudun koossa. Tämän johdosta myös tekemässäni ohjelmassa esiintyy puutteita. Esimerkiksi siitä pitää käyttäjää varten olla erillinen ohje, jossa kerrotaan, mitä ohjelman pyytämillä luvuilla kulloinkin tarkoitetaan. Syötettyjen lukujen korjausmahdollisuutta ei ohjelmassa myöskään ole.
Kaikkia ohjelmointikielen mahdollistamia etuja ei ohjelmassani ole käytetty hyväksi, koska ohjelma on tehty kaukana sivistyksestä, vaatimattomissa oloissa ilman 'printteriä' tai muitakaan apuvälineitä. Jälkeenpäin uudelleen tehtynä saattaisi ohjelma näyttää paljon yksinkertaisemmalta. Tähän uusimiseen en ole kuitenkaan ryhtynyt yksinkertaisesti riittävien testimahdollisuuksien puutteen vuoksi.
Nykyisin lienevät PC:t ja sylimikrot syrjäyttäneet ohjelmoitavat laskimet. Tämän johdosta olenkin Basic-ohjelman rinnalle rakentanut Excelille saman ohjelman.
TARVITTAVAT TOIMENPITEET
Paikanmääritystä varten tarvitaan kvartsikello, sekstantti, 'Nautical Almanac' ja ohjelmoitava laskin. Sekstantiksi riittää muovisekstantti, kunhan otetaan huomioon, että peilien säädön jälkeen pitää sekstanttia käsitellä varovaisesti. Ainakin alkuun paikanmääritykset on syytä tehdä valoisaan aikaan, koska hämäränajat ovat lyhyet ja horisontin havaitseminen vaikeaa. Venus näkyy aamu- tai iltatähtenä lähes valoisaan aikaan hämäränajan rajalla.
Sekstantilla mitataan auringon korkeus ja kellolla aika. Jos kuu ei ole auringon kanssa yhtäaikaa näkyvillä, saadaan havaintopaikka laskettua mittaamalla auringon korkeus aamupäivällä ja iltapäivällä. Myös tällöin saadaan ohjelmalla tulostettua suoraan havaintopaikka. Paikanmäärityksen tarkkuus tässä tapauksessa riippuu muun muassa siitä, kuinka tarkkaan kummankin eri aikaan tehdyn mittauksen välillä kuljettu matka ja suunta voidaan määritellä. Merkintäpaikan absoluuttisella tarkkuudella ei sinänsä ole merkitystä.
Laskutoimituksia varten käynnistetään ohjelma (ohjelmasta on tehty myös Excel-versio):
BASIC-OHJELMA200:AA=0:BB=0:CC=0:DD=0:EE=0
212:JK=0:INPUT "SUN=1 MOON=2 ";JK
214:IF JK<>0 THEN INPUT "LIMB L/U ";UL$:GOTO 220
216:INPUT "VENUS/MARS=3 ";JK:IF JK=3 THEN GOTO 220
218:INPUT "JUPITER/SATURN=4 ";JK
220:INPUT "A LAT ";I:GOSUB 900:LA=DEG I
222:INPUT "A LON ";I:GOSUB 900:LO=DEG I
224:INPUT "TIME HOUR ";T1,"MIN ";T2,"SEC ";T3
226:X=T2/60+T3/3600
228:INPUT "GHA ON H ";I:GOSUB 900:G1=DEG I
230:INPUT "GHA ON H+1";I:GOSUB 900:G2=DEG I
232:IF G2<G1 THEN LET G2=G2+360
234:GH=G1+X*(G2-G1)
235:IF JK>0 THEN GOTO 238
236:INPUT "SHA ";I:GOSUB 900:SH=DEG I:GH=GH+SH
238:IF GH>360 THEN LET GH=GH-360:GOTO 238
239:IF JK=0 THEN INPUT "DEC ";I:GOSUB 900:D=DEG I:GOTO 246
240:INPUT "DEC ON H ";I:GOSUB 900:D1=DEG I
242:INPUT "DEC ON H+1";I:GOSUB 900:D2=DEG I
244:D=D1+X*(D2-D1)
246:T=GH+LO
248:IF T>360 THEN LET T=T-360
250:IF T<0 THEN LET T=T+360
252:M=SIN LA:N=SIN D:O=COS LA:P=COS D:Q=COS T
254:HC=ASN (M*N+O*P*Q)
258:R=SIN HC:S=COS HC
260:Z=ACS ((N-M*R)/(O*S))
262:IF T<=180 THEN LET Z=360-Z
270:PRINT "HC ";HC:PRINT "AZM ";Z
300:INPUT "SEXT ALT ";I:GOSUB 900:HS=DEG I
310:INPUT "IND ERR ";I:GOSUB 900:IE=DEG I
320:INPUT "HT IN M ";HT:DP=.0293*SQR HT
330:H=HS+IE-DP
340:PM=0
350:INPUT "TEMP IN C ";TE,"PRESS IN MB ";PM
360:IF PM=0 THEN LET TE=10:PM=1010
370:RO=.0167/TAN (H+7.31/(H+4.4))
380:F=.28*PM/(TE+273)
390:R=F*RO
410:PA=0:OB=0:SD=0:HP=0
420:IF JK=0 OR JK=4 THEN GOTO 490
430:IF JK=1 THEN LET HP=.0024:INPUT "SD ";I:GOSUB 900:
SD=DEG I:GOTO 460
440:IF JK=2 THEN LET OB=-.0017*COS H
450:INPUT "HP ";I:GOSUB 900:HP=DEG I:SD=.2724*HP
460:PA=HP*COS H+OB
470:IF UL$="U" THEN LET HO=H-R+PA-SD:GOTO 500
490:HO=H-R+PA+SD
500:PRINT "HO ";HO
510:P=HO-HC:PO=P*60
512:PRINT "NM +T/-A ";PO
520:AA=AA+SQU COS Z
522:BB=BB+COS Z*SIN Z
524:CC=CC+SQU SIN Z
526:DD=DD+P*COS Z
528:EE=EE+P*SIN Z
530:INPUT "MORE FIX Y/N ";YN$
532:IF YN$="Y" THEN GOTO 212
540:G=AA*CC-SQU BB
550:BI=LA+(CC*DD-BB*EE)/G
552:LI=LO+(AA*EE-BB*DD)/(G*COS LA)
560:DO=60*SQR (SQU (LI-LO)*SQU COS LA+SQU (BI-LA))
562:I=BI:GOSUB 950:BI=I
564:I=LI:GOSUB 950:LI=I
566:DO= INT (DO*10)/10
570:PRINT "DIST ";DO,"LAT ";BI,"LON ";LI:END
900:Y=1:IF I<0 THEN LET Y=-1
910:I=ABS I:J= INT I
920:K=.6*(I-J)
930:I=Y*(J+K)/100: RETURN
950:Y=1:IF I<0 THEN LET Y=-1
960:I=ABS I:J= INT I
970:I=Y*(J*100+ INT ((I-J)*600)/10)
980:RETURN
OHJELMAN KÄYTTÖOHJEITA
Alkuun ohjelmassa riveillä 212-218 annetaan tieto, minkä taivaankappaleen korkeus on mitattu, ja sen jälkeen merkintäpaikan leveys- ja pituusasteet 'A LAT' ja 'A LON' aivan sellaisina kuin ne on laskettu. Koordinaateista syötetään ensin asteet, sitten minuutit kaksinumeroisena ja lopuksi minuuttien kymmenykset pisteellä erotettuna. Asteiden syöttö- ja tulostustapa ovat samat ohjelman joka kohdassa. Näin syötettynä aliohjelma riveillä 900-930 muuttaa luvut laskimen ymmärtämään muotoon. Aliohjelma tulostusta varten on riveillä 950-980.
Tietokonekautena on totuttauduttava käyttämään lukujen etumerkkejä. Siten ohjelmassani - yleisen käytännön mukaan - pohjoinen ja itäinen suunta merkitään positiivisena, eteläinen ja läntinen negatiivisena. Trigonometrisille funktioille tulee automaattisesti myös omat etumerkkinsä, jolloin ei tarvita plus-miinusvaihtoehtoja. Yllä olevassa Basic-ohjelmassa käytetään seuraavia termejä seuraavista funktiosta: ACS (arcus cos), ASN (arcus sin), ATN (arcus tan), SQU (neliöön koroitus), SQR (neliöjuuri).
Sitten syötetään mittaushetken tunnit 'HOUR', minuutit 'MIN' ja sekunnit 'SEC' kukin erikseen ja tämän jälkeen mittausaikaa edeltävän ja jälkeisen täyden tunnin GHA:t, SHA:t ja Dec:t siten kuin ohjelma pyytää. Luvut saadaan suoraan 'Nautikaalista'. Jos mitattu taivaankappale on tähti, syötetään Arieksen GHA:t. Ohjelma itse valitsee mitatun taivaankappaleen mukaan tarvittavat tiedot, jotka se ohjelman edistyessä pyytää.
Ohjelma kertoo sitten rivillä 270 välitietona, mikä on asteissa taivaankappaleen laskettu korkeus 'HO' ja tosisuuntima, atsimuutti 'AZM'.
Seuraavaksi ohjelma pyytää luetun korkeuden 'SEXT ALT', indeksivirheen 'IND ERR' ja mittauskorkeuden metreissä 'HT IN M'. Ulkoilman lämpötila 'TEMP IN C' ja ilmanpaine 'PRESS IN MB' voidaan syöttää tarvittaessa, mutta ne voidaan myös ENTERillä ohittaa.
Kun on syötetty vielä auringon puolihalkaisija 'SD' ja kuun horisontaalinen parallaksi 'HP', kertoo ohjelma, mikä on todettu korkeus 'HO' asteissa ja sijoittajan etäisyys merkintäpaikasta meripeninkulmissa 'NM +T/-A'. Tässä +T tarkoittaa 'Towards' ja -A 'Away'. Plus-merkkinen etäisyys mitataan taivaankappaleeseen päin ja miinus-merkkinen poispäin.
Tämän jälkeen ohjelma kysyy, halutaanko suorittaa muita laskutoimituksia 'MORE FIX Y/N'. Jos halutaan, ohjelma palaa alkuun komennolla 'Y'.
Viimeiseksi ohjelma laskee automaattisesti sijoittajien avulla havaintopaikan. Tätä varten se on koonnut eri mittausten tiedot riveillä 520-528. Ohjelma ilmoittaa havaintopaikan etäisyyden merkintäpaikasta meripeninkulmissa 'DIST' sekä sen leveys- ja pituusasteet 'LAT' ja 'LON' samassa muodossa kuin ohjelman alussa syötettiin merkintäpaikan koordinaatit. Etäisyys on viimeisimmän mittauksen merkintäpaikasta.
Korkeuden mittaukseen liittyvät epätarkkuudet suurentavat havaintopaikan sijainnin virheellisyyttä sitä enemmän, mitä pienemmän kulmaeron mitattujen taivaankappaleiden suuntimat muodostavat.
Mikäli etäisyys merkintäpaikasta on suuri, voidaan saatua havaintopaikkaa käyttää merkintäpaikkana ja laskea havaintopaikka uudelleen.
KEINOHORISONTIN KÄYTTÖ
Paikanmäärityksiä voidaan harjoitella lähes millon vain ja missä vain. Paikanmääritysharjoituksissa maalla voidaan horisontti korvata nimittäin vedenpinnalla. Tällöin menetellään seuraavalla tavalla.
Otetaan vettä laakeaan, mieluimmin tummaan yksiväriseen vatiin. Mitataan sekstantilla auringon ja auringon vedenpinnasta heijastuvan kuvan välinen kulma. Tämä tehdään siten, että auringon todellinen ja heijastunut kuva siirretään sekstantilla päällekkäin ja kulma luetaan. Mitattu kulma jaetaan kahdella, jolloin saadaan luettu korkeus.
Luettu korkeus on menetelmästä johtuen auringon keskipisteen korkeus. Korkeudesta on vähennettävä auringon puolihalkaisija SD, jolloin korkeus voidaan ohjelmassa syöttää auringon alareunan korkeudeksi 'SEXT ALT'. Horisontin alenemaa ei menetelmästä johtuen ole, joten mittauskorkeus = 0.
Auringon asemesta voidaan käyttää myös kuuta paikanmäärityksessä. Tai vieläpä kirkkaita tähtiä, jos niiden vedenpinnasta heijastunut kuva voidaan tunnistaa. Harjoitukset eivät näin ollen ole sidottuja päiväsaikaan.
Nykyisin ei enää paljon harrasteta Basic-ohjelmia kuten ennen, mutta tilalle on tullut sylimikrot ja taulukkolaskentaohjelmat. Edellä esitetty Basic-ohjelma on myös siirretty Excel-laskentataulukolle.
päivitetty 04.10.04.
Alla olevien Excel-taulukoiden imuroimiseksi on havaittu hyväksi menetelmä:klikkaa hiiren oikealla painikkeella ja taltioi haluamaasi kansioon.
Taulukoista on sinun hyvä ottaa aina varmuuskopio, jottet tarvitse imuroida uudelleen niitä, mikäli satut vahingossa muuttamaan niitä. Taulukot eivät ole nimittäin mitenkään lukittuja.
Mikäli taulukoiden käytö on jotain kysyttävää, voit lähettää e-mailin, soittaa tai kirjoittaa. Varsinkin tuo tähden tunnistus on testaamaton, joten mielelläni kuulisin siitä kommenttejasi, kuinka se toimii. Osoitteet löytyvät henkilötietosivulta.
Tähtitieteellinen paikanmääritys
Edellä olevan Basic-ohjelman korvaava Excel-laskenta (Excel-laskenta) tähtitieteellistä paikanmääritystä varten voit suoraan kopioida levyllesi. Voit taltioida myös saman taulukon esimerkkimuodossa, Excel-esimerkki (Excel-esimerkki), jossa piilotetut rivit ja sarakkeet on tuotu esiin ja johon on syötetty kahden autenttisen mittauksen lukemat.
Nyt on myös mahdollista imuroida tähtien/planeettojen tunnistamista varten taulukko: Excel-tunnistus (Excel-tunnistus). Sillä saat korkeuden mittauksen ja tosisuuntiman perusteella laskettua tähden/planeetan deklinaation sekä SHA:n ja GHA:n, joita arvoja almanakassa lähinnä oleva tähti on etsimäsi. (Ohjelmat on tehty Excel 5:llä, joten vastaava tai myöhäisempi versio pitäisi olla PC:ssä. Ohjelmat on tehty kahdessa eri muodossa, jollei suluton linkki avaa tiedostoa, niin voi kokeilla sulullista vastaavaa linkkiä.)
Enemmän tähtitieteellisen teoriaa on myös saatavilla.